RedCore/scripts/power_up.gd

class_name PowerUp
extends RigidBody2D
## A small token that falls from the top. Catch it with the paddle to collect it.

signal collected(power_up: PowerUp)

enum Kind {
	SAVE, TRIPLE_BALLS, PADDLE, SUPERBALL,
	SLOW, CATCH, SHIELD, BIG_BALL, FIREBALL, RUSH, LASER, FREEZE, BOMB, HOMING,
}

const RADIUS := 9.0
const FONT := preload("res://assets/fonts/abel.ttf")

## Per kind: colour, the letter on the token, first level it drops at, and its weight in
## the random pick. Triple balls are not in the pick: they drop when the ball is idle.
## Power-downs (down = true) get likelier as the levels go up.
const KINDS := {
	Kind.SAVE: { color = Params.COLOR_GREEN, glyph = "S", unlock = 0, weight = 0.6 },
	Kind.TRIPLE_BALLS: { color = Params.COLOR_PINK, glyph = "3", unlock = 0, weight = 0.0 },
	Kind.PADDLE: { color = Params.COLOR_BLUE, glyph = "P", unlock = 0, weight = 1.0 },
	Kind.SUPERBALL: { color = Params.COLOR_ORANGE, glyph = "X", unlock = 0, weight = 0.6 },
	Kind.SLOW: { color = Color("#5fb3ff"), glyph = "Z", unlock = 2, weight = 0.8 },
	Kind.CATCH: { color = Color("#8be28b"), glyph = "C", unlock = 4, weight = 0.8 },
	Kind.SHIELD: { color = Color("#f4f4f0"), glyph = "U", unlock = 6, weight = 0.7 },
	Kind.BIG_BALL: { color = Color("#c9c9c9"), glyph = "O", unlock = 8, weight = 0.7 },
	Kind.FIREBALL: { color = Params.COLOR_FIRE, glyph = "F", unlock = 12, weight = 0.6 },
	Kind.RUSH: { color = Params.COLOR_PINK, glyph = "!", unlock = 15, weight = 0.4, down = true },
	Kind.LASER: { color = Params.COLOR_RED, glyph = "L", unlock = 20, weight = 0.6 },
	Kind.FREEZE: { color = Color("#d6f3ff"), glyph = "*", unlock = 25, weight = 0.6 },
	Kind.BOMB: { color = Params.COLOR_BOMB, glyph = "B", unlock = 30, weight = 0.6 },
	Kind.HOMING: { color = Color("#ff8a8a"), glyph = "H", unlock = 40, weight = 0.5 },
}

var kind := Kind.SAVE


func _ready() -> void:
	add_to_group("power_ups")
	body_entered.connect(_on_body_entered)


## Weight of [param kind] in the random pick at [param level]; 0 when not unlocked yet.
static func weight(kind: Kind, level: int) -> float:
	var info: Dictionary = KINDS[kind]
	if level < info.unlock:
		return 0.0
	if info.get("down", false):
		return info.weight * Params.power_down_factor(level)
	return info.weight


func _on_body_entered(body: Node) -> void:
	if body is Paddle:
		collected.emit(self)
		queue_free()
	elif body.is_in_group("bottom"):
		queue_free()


func _draw() -> void:
	var color: Color = KINDS[kind].color
	draw_circle(Vector2.ZERO, RADIUS, color, true, -1.0, true)
	# Dark letters on light tokens, light letters on dark ones.
	var ink := Params.COLOR_BACK if color.get_luminance() > 0.5 else Color.WHITE
	var size := 14
	var text: String = KINDS[kind].glyph
	var text_size := FONT.get_string_size(text, HORIZONTAL_ALIGNMENT_LEFT, -1, size)
	draw_string(FONT, Vector2(-text_size.x / 2.0, FONT.get_ascent(size) / 2.0 - 1.0), text,
		HORIZONTAL_ALIGNMENT_LEFT, -1, size, ink)